lposcila
Prev | Orchestra Opcodes and Operators | Next

## lposcila

lposcila — Read sampled sound from a table with looping and high precision.

## Description

lposcila reads sampled sound from a table with looping and high precision.

## Syntax

    ar lposcila aamp, kfreqratio, kloop, kend, ift [,iphs]

## Initialization

ift -- function table number

iphs -- initial phase (in samples)

## Performance

ar -- output signal

aamp -- amplitude

kfreqratio -- multiply factor of table frequency (for example: 1 = original frequency, 1.5 = a fifth up , .5 = an octave down)

kloop -- start loop point (in samples)

kend -- end loop point (in samples)

lposcila is the same as lposcil, but has an audio-rate amplitude argument (instead of k-rate) to allow fast envelope transients.

## Examples

Here is an example of the lposcila opcode. It uses the file lposcila.csd.

Example 501. Example of the lposcila opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o lposcila.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kcps  = 1.3					;a 3d up
    kloop = 0					;loop start time in samples
    kend  = 10000					;loop end time in samples

    aenv expsega 0.01, 0.1, 1, 0.1, 0.5, 0.5, 0.01	;envelope with fast and short segment
    asig lposcila aenv, kcps, kloop, kend, 1	;use it for amplitude
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    ; Its table size is deferred,
    ; and format taken from the soundfile header.
    f 1 0 0 1 "beats.wav" 0 0 0

    ; Play Instrument #1 for 6 seconds.
    ; This will loop the drum pattern several times.
    i 1 0 2

    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

lposcil, lposcilsa, lposcilsa2

## Credits

Author: Gabriel Maldonado

New in version 5.06

Prev | Up | Next
lposcil3 | Home | lposcilsa