window
Prev | Orchestra Opcodes and Operators | Next

## window

window — Applies a window to an array.

## Description

Applies a given window shape to a vector stored in an array. The output is an array with the windowed vector.

## Initialization

itype -- optional window type: 0 = Hamming, 1 = Hanning (von Hann) (defaults to 1).

## Syntax

u

    kout[] window kin[][, koff, itype]

## Performance

kout[] -- output array containing the windowed output. It will be created if it does not exist.

kin[] -- input array containing the input vector.

koff -- offset to make window start at position koff (non-negative only, defaults to 0).

## Examples

Here is an example of the window opcode. It uses the file window.csd.

Example 1131. Example of the window opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>

    <CsOptions>
    -d -o dac
    </CsOptions>

    <CsInstruments>
    ;ksmps needs to be an integer div of hopsize
    ksmps = 64

    instr 1

     ihopsize = 256   ; hopsize
     ifftsize = 1024  ; FFT size
     iolaps = ifftsize/ihopsize ; overlaps
     ibw = sr/ifftsize ; bin bandwidth
     kcnt init 0    ; counting vars
     krow init 0

     kOla[] init ifftsize ; overlap-add buffer
     kIn[] init ifftsize  ; input buffer
     kOut[][] init iolaps, ifftsize ; output buffers

     a1 diskin2 "fox.wav",1,0,1 ; audio input

     /* every hopsize samples */
     if kcnt == ihopsize then
       /* window and take FFT */
       kWin[] window kIn,krow*ihopsize
       kSpec[] rfft kWin

       /* filter between high and low freqs */
       ilow = 0
       ihigh = 1000
       ki = int(ilow/ibw)
       until ki == int(ihigh/ibw) do
         kSpec[ki] = 0
         ki += 1
       od

       /* IFFT + window */
       kRow[] rifft kSpec
       kWin window kRow, krow*ihopsize
       /* place it on out buffer */
       kOut setrow kWin, krow

       /* zero the ola buffer */
       kOla = 0
       /* overlap-add */
       ki = 0
       until ki == iolaps do
         kRow getrow kOut, ki
         kOla = kOla + kRow
         ki += 1
       od

      /* update counters */
      krow = (krow+1)%iolaps
      kcnt = 0
     endif

     /* shift audio in/out of buffers */
     kIn shiftin a1
     a2 shiftout kOla
        out a2/iolaps

     /* increment counter */
     kcnt += ksmps

    endin

    </CsInstruments>

    <CsScore>
    i1 0 10
    </CsScore>

    </CsoundSynthesizer>

## See Also

Vectorial opcodes, array opcodes

## Credits

Author: Victor Lazzarini
NUI Maynooth
2014

New in version 6.04

Prev | Up | Next
wiisend | Home | wrap