dcblock2
Prev | Orchestra Opcodes and Operators | Next

## dcblock2

dcblock2 — A DC blocking filter.

## Description

Implements a DC blocking filter with improved DC attenuation.

## Syntax

    ares dcblock2 ain [, iorder] [, iskip]

## Initialization

iorder -- filter order, minimum 4th order, defaults to 128.

iskip -- set to 1 to skip initialization (defaults to 0).

## Performance

ares -- filered audio signal

ain -- input audio signal

| Note
Using a value for iorder less that ksmps will not reduce DC offset efficiently.

## Examples

The result can be viewed in a graphical audio editor program like audacity. audacity is available for Linux, Windows, and the MacOS and may be downloaded from http://audacity.sourceforge.net.

Here is an example of the dcblock2 opcode. It uses the file dcblock2.csd, and beats.wav.

Example 186. Example of the dcblock2 opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ;-o dcblock2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2

    instr 1	;add DC to "beats.wav"

    asig soundin "beats.wav"
    asig = asig+5000	;adds DC of 5000
         outs asig, asig
    endin

    instr 2	;dcblock audio

    asig soundin "beats.wav"
    asig = asig+5000	;adds DC
    adc  dcblock2 asig	;remove DC again
         outs adc, adc

    endin

    </CsInstruments>
    <CsScore>

    i 1 0 2
    i 2 2 2
    e

    </CsScore>
    </CsoundSynthesizer>

## See also

dcblock

## Credits

By: Victor Lazzarini

New in Csound version 5.09

Prev | Up | Next
dcblock | Home | dconv